批处理打不开help文档

Question

主要是由于前面的version通不过去，所以想把它简化一下，直接打开help

 @echo off
REM Use this script to manually start the Java Help System
REM
REM Usage: startJavaHelp
REM
SETLOCAL
set EMPTY_STRING=

REM Windows XP
ver | find "5.1" > nul
IF %ERRORLEVEL% == 0 goto setWinXP2003Workspace

REM Windows Server 2003
ver | find "5.2" > nul
if %ERRORLEVEL% == 0 goto setWinXP2003Workspace

REM Windows Vista or Server 2008
ver | find "6.0" > nul
if %ERRORLEVEL% == 0 goto setWinVista78Server0812Workspace

REM Windows 7
ver | find "6.1" > nul
if %ERRORLEVEL% == 0 goto setWinVista78Server0812Workspace

REM Windows 8 or Windows Server 2012
ver | find "6.2" > nul
if %ERRORLEVEL% == 0 goto setWinVista78Server0812Workspace

REM Windows 8.1 or Windows Server 2012 R2
ver | find "6.3" > nul
if %ERRORLEVEL% == 0 goto setWinVista78Server0812Workspace

echo You are not using a supported Windows Operating System.  See http://support.esri.com for a list.
pause
goto end

:setWinXP2003Workspace
set WORKSPACE_HOME=%USERPROFILE%\Local Settings\Application Data\ESRI\DevKit10.0\JHSWorkspace
goto continue

:setWinVista78Server0812Workspace
set WORKSPACE_HOME=%USERPROFILE%\AppData\Local\ESRI\DevKit10.0\JHSWorkspace
goto continue

:continue
if not ("%AGSDEVKITJAVA%")==("%EMPTY_STRING%") set JAVAW=%AGSDEVKITJAVA%java\jre\bin\javaw.exe
if exist "%JAVAW%" goto setVariables

goto errorMessageDevKit

:setVariables
set HELP_SYSTEM_COMMAND=displayHelp
set HELP_SYSTEM_HOME=%AGSDEVKITJAVA%java\docs\eclipse
set PLUGIN_VERSION=3.3.100.v20080201
set HELP_SYSTEM_JAR=%HELP_SYSTEM_HOME%\plugins\org.eclipse.help.base_%PLUGIN_VERSION%.jar

start "%EMPTY_STRING%" "%JAVAW%" -classpath "%HELP_SYSTEM_JAR%" org.eclipse.help.standalone.Help -command %HELP_SYSTEM_COMMAND% -eclipsehome "%HELP_SYSTEM_HOME%" -data "%WORKSPACE_HOME%" -refresh -clean

echo When finished, run %HELP_SYSTEM_HOME%\stopJavaHelp.bat
echo Starting the Java Help System . . .
goto end

:errorMessageDevKit
echo Unable to find the AGSDEVKITJAVA environment variable.
echo Check to make sure the Java ArcObjects SDK has been installed and computer rebooted.
pause
goto end

:end

Answer 1

最后自己解决了，是由于环境变量的问题，要把系统的环境变量放在最前边才可以。