C语言问题，编写一个将C语言 变成 MIPS 汇编程序

Question

望各位帮忙看看，现在就想要答案，蟹蟹各位潜水专家，感谢解答，感谢回答，感谢解答。编写一个 MIPS 汇编程序，相当于这个 C 程序：在原有的基础上完成这个程序。在# PUT YOUR CODE HERE下面写内容.我需要答案，不要告诉我需要自己下什么东西然后就可以得到，我想要的是直接把代码告诉我

// Read 10 numbers into an array
// then print the numbers which are
// larger than the last number read.
#include <stdio.h>
int main(void) {
    int i, last_number;
    int numbers[10] = { 0 };
    i = 0;
    while (i < 10) {
        scanf("%d", &numbers[i]);
        last_number = numbers[i];
        i++;
    }
    i = 0;
    while (i < 10) {
        if (numbers[i] >= last_number) {
            printf("%d\n", numbers[i]);
        }
        i++;
    }
}
 

 
# Read 10 numbers into an array
# then print the numbers which are
# larger than the last number read.
# i in register $t0
# registers $t1, $t2 & $t3 used to hold temporary results
main:
    li   $t0, 0         # i = 0
loop0:
    bge  $t0, 10, end0  # while (i < 10) {
    li   $v0, 5         #   scanf("%d", &numbers[i]);
    syscall             #
    mul  $t1, $t0, 4    #   calculate &numbers[i]
    la   $t2, numbers   #
    add  $t3, $t1, $t2  #
    sw   $v0, ($t3)     #   store entered number in array
    addi $t0, $t0, 1    #   i++;
    j    loop0          # }
end0:
 
    li   $t0, 0         # i = 0
loop1:
    bge  $t0, 10, end1  # while (i < 10) {
    mul  $t1, $t0, 4    #   calculate &numbers[i]
    la   $t2, numbers   #
    add  $t3, $t1, $t2  #
    lw   $a0, ($t3)     #   load numbers[i] into $a0
    li   $v0, 1         #   printf("%d", numbers[i])
    syscall
    li   $a0, '\n'      #   printf("%c", '\n');
    li   $v0, 11
    syscall
    addi $t0, $t0, 1    #   i++
    j    loop1          # }
end1:
    jr   $ra              # return
.data
numbers:
    .word 0, 0, 0, 0, 0, 0, 0, 0, 0, 0  # int numbers[10] = {0};

Answer 1

代码如下
有帮助望采纳~

 
# Read 10 numbers into an array
# then print the numbers which are
# larger than the last number read.
# i in register $t0
# registers $t1, $t2 & $t3 used to hold temporary results
main:
    li   $t0, 0         # i = 0
loop0:
    bge  $t0, 10, end0  # while (i < 10) {
    li   $v0, 5         #   scanf("%d", &numbers[i]);
    syscall             #
    mul  $t1, $t0, 4    #   calculate &numbers[i]
    la   $t2, numbers   #
    add  $t3, $t1, $t2  #
    sw   $v0, ($t3)     #   store entered number in array
    addi $t4,$v0,0      # store last number
    addi $t0, $t0, 1    #   i++;
    j    loop0          # }
end0:
    li   $t0, 0         # i = 0
loop1:
    bge  $t0, 10, end1  # while (i < 10) {
    mul  $t1, $t0, 4    #   calculate &numbers[i]
    la   $t2, numbers   #
    add  $t3, $t1, $t2  #
    
    lw   $a0, ($t3)     #   load numbers[i] into $a0
    addi $t0, $t0, 1    #   i++
    blt $a0,$t4,loop1
    li   $v0, 1         #   printf("%d", numbers[i])
   
    syscall
    li   $a0, '\n'      #   printf("%c", '\n');
    li   $v0, 11
    syscall
    
    j    loop1          # }
end1:
    jr   $ra              # return
.data
numbers:
    .word 0, 0, 0, 0, 0, 0, 0, 0, 0, 0  # int numbers[10] = {0};