求教OpenGL红宝书第五章的碰撞检测算法的原理

Question

代码如下：

bool intersect(vec3 origin, vec3 direction, vec3 v0, vec3 v1, vec3 v2, out vec3 point)
            {
                vec3 u, v, n;
                vec3 w0, w;
                float r, a, b;
                u = (v1 - v0);
                v = (v2 - v0);
                n = cross(u, v);
                a = -dot(n, w0);
                b = dot(n, direction);
                r = a / b;
                if (r < 0.0 || r > 1.0)
                    return false;
               point = origin + r * direction;
               float uu, uv, vv, wu, wv, D;
               uu = dot(u, u);
               uv = dot(u, v);
               vv = dot(v, v);
               w = point - v0;
               wu = dot(w, u);
               wv = dot(w, v);
               D = uv * uv - uu * vv;
               float s, t;
               s = (uv * wv - vv * wu) / D;
               if (s < 0.0 || s > 1.0)
                   return false;
               t = (uv * wu - uu * wv) / D;
               if (t < 0.0 || (s + t) > 1.0)
                   return false;
               return true;
            }

函数参数中origin 是点的起始位置，direction是运动方向，v0、v1、v2是一个三角平面的三个顶点。从a = -dot(n, w0);这里我就不太懂了，请大神看看。
我个人的理解是求出三角平面的法向量n后，根据点的初始位置及运动方向判断是否和平面相交。但是使用的代码原理我看不懂。

Answer 1

//intersect算法说明如下

bool intersect(vec3 origin, vec3 direction, vec3 v0, vec3 v1, vec3 v2, out vec3 point)
{
vec3 u, v, n;
vec3 w0, w;
float r, a, b;
u = (v1 - v0);
v = (v2 - v0);
n = cross(u, v);
w0 = origin - v0;
a = -dot(n, w0); //w0在n上的投影距离*|n|，w0在n上的投影距离就是origin点离三角形所在平面的距离
b = dot(n, direction); //direction在n上的投影距离*|n|
r = a / b; // (w0在n上的投影距离)/(direction在n上的投影距离)
if (r < 0.0 || r > 1.0) //如果direction指向三角形，同时direction在n上的投影距离 >= w0在n上的投影距离，说明origin射线穿过三角形所在平面，否则与平面没有交点
return false;
point = origin + r * direction; //根据三角形等比定律，计算出origin射线与三角形所在平面的交点

//使用三角形重心法判断交点是否位于三角形内部，网上有标准计算公式
float uu, uv, vv, wu, wv, D;
uu = dot(u, u);
uv = dot(u, v);
vv = dot(v, v);
w = point - v0;
wu = dot(w, u);
wv = dot(w, v);
D = uv * uv - uu * vv;
float s, t;
s = (uv * wv - vv * wu) / D;
if (s < 0.0 || s > 1.0)
return false;
t = (uv * wu - uu * wv) / D;
if (t < 0.0 || (s + t) > 1.0)
return false;
return true;
}