delphi richedit里比较文字？

Question

比如：richedit1里有“DELPHI”。
richedit2里有“DELPHI是一门开发语言”。
那么单击按钮richedit2里的"DELPHI"就以红色加组字体显示，其他的不变。

麻烦老师给个思路或者实例参考！

///////
就是要这样的效果呢？

RichEdit2里的文字，R和我显示红色。

Answer 1

新代码, 通过空格分割要高亮的内容, 你把你图片里的顿号改成空格就行了

 procedure TForm1.Button1Click(Sender: TObject);

  procedure _HighLightText(AStr: string);
  var
    nPos, nStrLength, nAllLength: Integer;
  begin
    nPos := 0;
    nAllLength := RichEdit2.GetTextLen;
    nStrLength := Length(AStr);
    nPos := RichEdit2.FindText(AStr, nPos, nAllLength, [stMatchCase]); //如果大小写不敏感就用[]
    while nPos > -1 do //如果只想高亮第一个就不用循环
    begin
      RichEdit2.SelStart := nPos;
      RichEdit2.SelLength := nStrLength;
      RichEdit2.SelAttributes.Color := clRed;
      nPos := nPos + nStrLength;
      nPos := RichEdit2.FindText(AStr, nPos, nAllLength, [stMatchCase]);
    end;
  end;

var
  nStr: string;
  i: Integer;
begin
  RichEdit2.SelectAll;
  RichEdit2.SelAttributes := RichEdit2.DefAttributes;

  with TStringList.Create do
  try
    StrictDelimiter := True;
    Delimiter := ' '; //这里规定要高亮的内容用空格分隔
    DelimitedText := RichEdit1.Text;
    for i := 0 to Count - 1 do
    begin
      nStr := Strings[i].Trim;
      if nStr <> '' then
        _HighLightText(nStr);
    end;
  finally
    Free;
  end;
end;