unity里的shader gpu动画问题，如何动态改变动画，每次从第一帧播放

Question

关于unity的shader，gpu动画

/*
Created by jiadong chen
https://jiadong-chen.medium.com/
*/

Shader "chenjd/BuiltIn/AnimMapShader"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
        _AnimTex ("Texture", 2D) = "white" {}
        _AnimTime ("AnimTime", float) = 1
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        LOD 100
        
        Pass
        {
            CGPROGRAM
            #pragma target 3.5
            #pragma vertex vert
            #pragma fragment frag
            // make fog work
            #pragma multi_compile_instancing
            
            #include "UnityCG.cginc"
            
            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
                uint vid : SV_VERTEXID;
                UNITY_VERTEX_INPUT_INSTANCE_ID
            };
            
            struct v2f
            {
                float2 uv : TEXCOORD0;
                UNITY_FOG_COORDS(1)
                float4 vertex : SV_POSITION;
                UNITY_VERTEX_INPUT_INSTANCE_ID
            };
            
            CBUFFER_START(UnityPerMaterial)
                sampler2D _MainTex;
                sampler2D _AnimTex;
                
                UNITY_INSTANCING_BUFFER_START(Props)
                UNITY_DEFINE_INSTANCED_PROP(float4, _AnimTex_TexelSize)
                UNITY_DEFINE_INSTANCED_PROP(float4, _MainTex_ST)
                UNITY_DEFINE_INSTANCED_PROP(float, _AnimTime)
                UNITY_INSTANCING_BUFFER_END(Props)
            CBUFFER_END
            
            v2f vert (appdata v)
            {
                v2f o;                
                UNITY_SETUP_INSTANCE_ID(v);
                UNITY_TRANSFER_INSTANCE_ID(v, o);
                float4 uv_anim = float4((v.vid + 0.5) * UNITY_ACCESS_INSTANCED_PROP(Props, _AnimTex_TexelSize).x, _Time.y / UNITY_ACCESS_INSTANCED_PROP(Props, _AnimTime),0.0,0.0);
                v.vertex = float4(tex2Dlod(_AnimTex, uv_anim).xyz,1.0);
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uv = v.uv * UNITY_ACCESS_INSTANCED_PROP(Props, _MainTex_ST).xy + UNITY_ACCESS_INSTANCED_PROP(Props, _MainTex_ST).zw;
                return o;
            }
            
            fixed4 frag (v2f i) : SV_Target
            {
                UNITY_SETUP_INSTANCE_ID(i);
                fixed4 col = tex2D(_MainTex, i.uv);
                return col;
            }
            ENDCG
        }
    }
}

如果我要动态改变动画。
float4 uv_anim = float4((v.vid + 0.5) * UNITY_ACCESS_INSTANCED_PROP(Props, _AnimTex_TexelSize).x, _Time.y / UNITY_ACCESS_INSTANCED_PROP(Props, _AnimTime),0.0,0.0);
这里 _Time.y / UNITY_ACCESS_INSTANCED_PROP(Props, _AnimTime),0.0,0.0);应该是取动画的进度。但是这个时间是一直在走的。那么动画如何才能每次都从0帧开始播放呢？我在游戏场景里调试，发现有时动画不是从头开始播放的。

Answer 1

这个问题我自己解决了，float animTime=_Time.y-UNITY_ACCESS_INSTANCED_PROP(Props, _StartTime);
播放动画的时候，通过block.SetFloat(_StartTime,Time.timeSinceLevelLoad);设置一个起始时间。
动画里的时间减去这个起始时间，就可以达到每次从第0帧开始播放了